Mencocokan isi registry di RobzLabz Blog

Mencocokan isi registry dapat kita lakukan dengan cara yang cukup mudah karena sudah terdapat function yang digunakan untuk membaca registry yang telah disediakan oleh visual basic, oke kali ini kita mempunyai misi untuk mencocokan value yang ada pada program kita dengan key yang ada dalam registry. Cara ini digunakan dalam beberapa antivirus/registry tweaking/cleaner untuk memastikan registry pada windows aman atau registry benar

Karena program ini dibuat sesimple mungkin, maka dengan program visual basic buatlah tampilan seperti di bawah ini

Tampilan Aplikasi Cek Registry

Pada form tersebut terdapat button dengan nama cmdCheck dan textbox dengan nama txtDefaultValue. Oke, setelah kita membuat tampilannya mari kita membuat sedikit baris kodenya

Copas code di bawah ini :)

Option Explicit

' Reg Key Security Options...
Const READ_CONTROL = &H20000
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_CREATE_LINK = &H20
Const KEY_ALL_ACCESS = KEY_QUERY_VALUE + KEY_SET_VALUE + _
                       KEY_CREATE_SUB_KEY + KEY_ENUMERATE_SUB_KEYS + _
                       KEY_NOTIFY + KEY_CREATE_LINK + READ_CONTROL
                     
' Reg Key ROOT Types...
Const HKEY_LOCAL_MACHINE = &H80000002
Const ERROR_SUCCESS = 0
Const REG_SZ = 1                         ' Unicode nul terminated string
Const REG_DWORD = 4                      ' 32-bit number

Private Declare Function RegOpenKeyEx Lib "advapi32" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, ByRef phkResult As Long) As Long
Private Declare Function RegQueryValueEx Lib "advapi32" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, ByRef lpType As Long, ByVal lpData As String, ByRef lpcbData As Long) As Long
Private Declare Function RegCloseKey Lib "advapi32" (ByVal hKey As Long) As Long



Public Function GetKeyValue(KeyRoot As Long, KeyName As String, SubKeyRef As String, ByRef KeyVal As String) As Boolean
    Dim i As Long                                           ' Loop Counter
    Dim rc As Long                                          ' Return Code
    Dim hKey As Long                                        ' Handle To An Open Registry Key
    Dim hDepth As Long                                      '
    Dim KeyValType As Long                                  ' Data Type Of A Registry Key
    Dim tmpVal As String                                    ' Tempory Storage For A Registry Key Value
    Dim KeyValSize As Long                                  ' Size Of Registry Key Variable
    '------------------------------------------------------------
    ' Open RegKey Under KeyRoot {HKEY_LOCAL_MACHINE...}
    '------------------------------------------------------------
    rc = RegOpenKeyEx(KeyRoot, KeyName, 0, KEY_ALL_ACCESS, hKey) ' Open Registry Key
    
    If (rc <> ERROR_SUCCESS) Then GoTo GetKeyError          ' Handle Error...
    
    tmpVal = String$(1024, 0)                             ' Allocate Variable Space
    KeyValSize = 1024                                       ' Mark Variable Size
    
    '------------------------------------------------------------
    ' Retrieve Registry Key Value...
    '------------------------------------------------------------
    rc = RegQueryValueEx(hKey, SubKeyRef, 0, _
                         KeyValType, tmpVal, KeyValSize)    ' Get/Create Key Value
                        
    If (rc <> ERROR_SUCCESS) Then GoTo GetKeyError          ' Handle Errors
    
    If (Asc(Mid(tmpVal, KeyValSize, 1)) = 0) Then           ' Win95 Adds Null Terminated String...
        tmpVal = Left(tmpVal, KeyValSize - 1)               ' Null Found, Extract From String
    Else                                                    ' WinNT Does NOT Null Terminate String...
        tmpVal = Left(tmpVal, KeyValSize)                   ' Null Not Found, Extract String Only
    End If
    '------------------------------------------------------------
    ' Determine Key Value Type For Conversion...
    '------------------------------------------------------------
    Select Case KeyValType                                  ' Search Data Types...
    Case REG_SZ                                             ' String Registry Key Data Type
        KeyVal = tmpVal                                     ' Copy String Value
    Case REG_DWORD                                          ' Double Word Registry Key Data Type
        For i = Len(tmpVal) To 1 Step -1                    ' Convert Each Bit
            KeyVal = KeyVal + Hex(Asc(Mid(tmpVal, i, 1)))   ' Build Value Char. By Char.
        Next
        KeyVal = Format$("&h" + KeyVal)                     ' Convert Double Word To String
    End Select
    
    GetKeyValue = True                                      ' Return Success
    rc = RegCloseKey(hKey)                                  ' Close Registry Key
    Exit Function                                           ' Exit
    
GetKeyError:      ' Cleanup After An Error Has Occured...
    KeyVal = ""                                             ' Set Return Val To Empty String
    GetKeyValue = False                                     ' Return Failure
    rc = RegCloseKey(hKey)                                  ' Close Registry Key
End Function

Kode tersebut sebenarnya adalah code yang sudah otomatis di generate oleh visual basic ketika kita membuat frmAbout, oke taruh kode tersebut ke dalam form yang sudah kita buat, lalu mari kita fokuskan pada function yang ada di code tersebut

Public Function GetKeyValue(KeyRoot As Long, KeyName As String, SubKeyRef As String, ByRef KeyVal As String) As Boolean

Dalam kode tersebut terdapat function bernama GetKeyValue yang mempunyai parameter KeyRoot yang akan di isi dengan variabel bertipe long dan sudah di deklarasikan di atas. KeyName adalah kunci dari lokasi di registry. SubKeyRef adalah nama dari kunci dan yang terakhir adalah KeyVal yaitu parameter yang bertipe string yang digunakan untuk isi dari KeyVal registry.

Kunci Kunci Pada Registry

Oke, mari kita coba gunakan function tersebut untuk mengecek/mencocokan kunci yang kita miliki dengan yang ada pada registry

Private Sub cmdCheck_Click()
    Dim Path As String
    Dim SubKey As String
    Dim Value As String
    
    Path = "Software\RobzLabz"
    SubKey = "myword"
    
    If GetKeyValue(HKEY_LOCAL_MACHINE, Path, SubKey, Value) Then
        If Value = txtDefaultValue Then
            MsgBox "Sama Bro"
        Else
            MsgBox "Tidak Sama"
        End If
    End If
    
End Sub

double click pada cmdCheck lalu otomatis cursor akan diarahkan pada baris kode btnCheck
Mula mula kita buat 3 variabel dengan tipe string, path digunakan untuk menampung lokasi registry, subkey digunakan untuk menampung nama keynya dan Value digunakan untuk menampung isi dari registey yang ada

Path diisikan "Software\RobzLabz" karena kita akan bekerja di derektori tersebut, Subkey di isi dengan myword karena myword adalah nama dari key yang akan kita gunakan dan Value akan di isi oleh function tersebut karena pada parameter KeyVal ada ByRef. lalu kita mengisikan permisalan, jika GetKeyValue(...) maka masuk. Disini maksudnya adalah jika SubKey ditemukan maka nilainya adalah true dan sebaliknya. Kedua, jika Value (isi registry) sama dengan txtDefaultValue maka program akan menampilkan pesan "Sama Bro" dan jika tidak sama maka akan menampilkan pesan "tidak sama"

Catatan : HKLM (HKEY_LOCAL_MACHINE) adalah constanta yang telah dibuat sebelumnya

Oke, logikanya seperti ini, ketika kita click cmdCheck maka program akan membaca registry di HKLM\Software\RobzLabz dengan nama myword dan mencocokan txtdefaultValue dengan value yang ada di registry, lalu program akan menampilkan pesan sama atau tidak sama